Re: Ghostscript 7.05 と Ghostscript 7.04の共存について

名前: 角藤
日時: 2002-11-21 13:02:41
IPアドレス: 157.13.51.*

>>13090

>あれから個人的に調べたこととしては、GS_LIBをAFPL gs7.04用の設定とし、
>ps2pdfだけをGNU gs 7.05で使おうと試みた
>（具体的にはC:\gs\gs7.05\lib\ps2pdf のようにfull pathで指定した）の
>ですが、AFPL gs7.04が使われてしまうようです。

batch ファイルには gswin32c としか書いてありませんから、
PATH に出てくる早いほうが使われます。

>（出力されたメッセージより。％以下のコメント行のような形だったと思います。）
>GNU gs7.05を明示的に指定するオプションがあると期待したのですが、
>添付文書には書いてありませんでした・・・。

gssetgs.bat を次のように変更し、

@echo off
@rem $Id: gssetgs.bat,v 1.3 2001/06/22 16:09:22 lpd Exp $

rem Set default values for GS (gs with graphics window) and GSC
rem (console mode gs) if the user hasn't set them.

if %GS%/==/ set GS=c:\gs\gs7.05\bin\gswin32
if %GSC%/==/ set GSC=c:\gs\gs7.05\bin\gswin32c


また、ps2pdfxx.bat を次のように変更すると ps2pdf 関係では
gs7.05  が使われるでしょう。
(gs7.04 のほうの ps2pdf.bat や ps2pdf??.bat は消去しておくとよいでしょう) 

@echo off
@rem $Id: ps2pdfxx.bat,v 1.10 2001/06/22 16:09:22 lpd Exp $
rem Internal batch file for calling pdfwrite driver.

rem The files that call this one (ps2pdf*.bat) write the command-line
rem options into _.at, and then pass the last 2 (or fewer) arguments
rem to this file.

call gssetgs.bat
echo "-q -Ic:/gs/fonts;c:/gs/gs7.05/lib -dSAFER -dNOPAUSE -dBATCH -sDEVICE#pdfwrite" >_.at2

if "%OS%"=="Windows_NT" goto nt

rem	Run ps2pdf on any Microsoft OS.

if %1/==/ goto usage
if %2/==/ goto usage

rem Watcom C deletes = signs, so use # instead.
rem We have to include the options twice because -I only takes effect if it
rem appears before other options.

:run
echo -sOutputFile#%2 >>_.at2
copy /b /y _.at2+_.at >NUL
echo -c .setpdfwrite -f %1 >>_.at2
%GSC% @_.at @_.at2
goto end

:usage
echo Usage: ps2pdf [options...] input.[e]ps output.pdf
goto end

rem	Run ps2pdf on Windows NT.

:nt
if not CMDEXTVERSION 1 goto run
if %1/==/ goto ntusage
if %2/==/ goto nooutfile
goto run

:ntusage
echo Usage: ps2pdf input.ps [output.pdf]
echo    or: ps2pdf [options...] input.[e]ps output.pdf
goto end

:nooutfile
rem We don't know why the circumlocution with _1 is needed....
set _1=%1
call ps2pdfxx %1 %_1:.PS=.pdf%
set _1=

:end
rem	Clean up.
if exist _.at erase _.at
if exist _.at2 erase _.at2

この書き込みへの返事：